VBAで要件(ポリシー)に沿ったランダムパスワードを生成

' パスワード用のランダム文字列を生成する
Public Function GeneratePassword(iLength As Integer, Optional bAllowLower As Boolean = True, Optional bAllowUpper As Boolean = True, _
  Optional bAllowNumber As Boolean = True, Optional bAllowSymbol As Boolean = False, Optional bRequireLower As Boolean = True, _
  Optional bRequireUpper As Boolean = True, Optional bRequireNumber As Boolean = True, Optional bRequireSymbol As Boolean = False, _
  Optional sSymbols As String = "!#$%&()=^-|@[]{}:;,.") As String
    Dim sPassword As String
    Dim i As Long
    Dim sTotalChars As String
   
    Const S_LOWER As String = "abcdefghijklmnopqrstuvwxyz"
    Const S_UPPER As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    Const S_NUMBER As String = "0123456789"
   
    ' 使用可能文字種
    If bAllowLower Then
        sTotalChars = sTotalChars & S_LOWER
    End If
    If bAllowUpper Then
        sTotalChars = sTotalChars & S_UPPER
    End If
    If bAllowNumber Then
        sTotalChars = sTotalChars & S_NUMBER
    End If
    If bAllowSymbol Then
        sTotalChars = sTotalChars & sSymbols
    End If
   
    ' 任意の文字種が可能な部分を生成
    For i = 1 To iLength - Abs(bRequireLower + bRequireUpper + bRequireNumber + bRequireSymbol)
        sPassword = sPassword & Mid(sTotalChars, Int(Len(sTotalChars) * Rnd + 1), 1)
    Next i
   
    ' 必須とされる文字種の文字を1文字ずつ挿入
    If bRequireLower Then
        i = Int((Len(sPassword) + 1) * Rnd + 1)
        sPassword = Mid$(sPassword, 1, i - 1) & Mid(S_LOWER, Int(Len(S_LOWER) * Rnd + 1), 1) & Mid$(sPassword, i)
    End If
    If bRequireUpper Then
        i = Int((Len(sPassword) + 1) * Rnd + 1)
        sPassword = Mid$(sPassword, 1, i - 1) & Mid(S_UPPER, Int(Len(S_UPPER) * Rnd + 1), 1) & Mid$(sPassword, i)
    End If
    If bRequireNumber Then
        i = Int((Len(sPassword) + 1) * Rnd + 1)
        sPassword = Mid$(sPassword, 1, i - 1) & Mid(S_NUMBER, Int(Len(S_NUMBER) * Rnd + 1), 1) & Mid$(sPassword, i)
    End If
    If bRequireSymbol Then
        i = Int((Len(sPassword) + 1) * Rnd + 1)
        sPassword = Mid$(sPassword, 1, i - 1) & Mid(sSymbols, Int(Len(sSymbols) * Rnd + 1), 1) & Mid$(sPassword, i)
    End If
   
    GeneratePassword = sPassword

End Function

B9ZJQVrseM
wYkkAE9cU0
feWc79QQ1S
jq1bu3ocVR
9MeCMCg6ls
7TAFCkC1zR
ZudA9RE6ZN
xv7xsXn3V3
vHZjXA9HeA
hbxE3k0ZOM

b:t8r@KG^n
&Wp}vjT1bA
q(5u,o1[Kw
7W,^y2MUtb
eXO-NKb4)$
[3rW48O3.=
i73zhvZS)F
=#%8FpVEIQ
nS0troQ:G(
31.w.FDLM6